• caso de arreglos en lpp

/*
APLICACION QUE PERMITA REGISTRAR A VARIOS ALUMNOS JUNTO CON
LAS NOTAS DE SUS 3 PRÁCTICAS DE UN CURSO.
NO SE SABE DE MANERA PREDETERMINADA CUANTOS ALUMNOS SON.
SE REQUIERE:
1) LISTADO DE ALUMNOS CON SUS NOTAS, PROMEDIO
   Y ESTADO (APROBADO O DESAPROBADO)
2) LISTADO ORDENADO ALFABETICAMENTE
3) LISTADO ORDENADO DESCENDENTEMENTE POR PROMEDIO
4) HALLAR LA MÁXIMA NOTA (PROMEDIO)
5) LISTADO DE ALUMNOS APROBADOS
6) LISTADO DE ALUMNOS DESAPROBADOS
*********
7) HALLAR EL NRO. DE APROBADOS Y DESAPROBADOS
8) MODIFIQUE LA APLICACION PARA ALMACENAR EL CODIGO DEL ALUMNO
   Y EL NOMBRE DEL CURSO
----------
9) LA aplicacion DEBE REALIZAR BUSQUEDAS POR CODIGO DE ALUMNO

*/

//DECLARANDO EL REGISTRO
REGISTRO REG_ALUMNO
CADENA [5] CODIGO //CODIGO UNIVERSITARIO
CADENA [30] ALUMNO //NOMBRE DEL ALUMNO
CADENA [30] CURSO  //NOMBRE DEL CURSO
ENTERO P1 //PRACTICA 1
ENTERO P2 //PRACTICA 2
ENTERO P3 //PRACTICA 3
REAL PROMEDIO //EL PROMEDIO DE LAS PRACTICAS
FIN REGISTRO
//------ VARIABLES DEL MODULO PRINCIPAL -----
ARREGLO[200] DE REG_ALUMNO ARR_REGISTRO
ENTERO N, POS
CARACTER OPCION
REAL PMAY
CADENA [5] COD //PARA LA BUSQUEDA
// --- SUBRUTINAS ----
PROCEDIMIENTO RECUADRO(ENTERO X1, ENTERO Y1, ENTERO X2, ENTERO Y2,ENTERO COLOR, CARACTER SIMBOLO, ENTERO TIEMPO)
ENTERO J
INICIO
LLAMAR COLOR_TEXTO(COLOR)
//DIBUJANDO LAS LINEAS HORIZONTALES
PARA J<- X1 HASTA X2 HAGA

LLAMAR POSICIONAR_CURSOR(J, Y1)
LLAMAR RETRASO(TIEMPO)
ESCRIBA SIMBOLO

LLAMAR POSICIONAR_CURSOR(J, Y2)
LLAMAR RETRASO(TIEMPO)
ESCRIBA SIMBOLO
FIN PARA
//DIBUJANDO LAS LINEAS VERTICALES
PARA J<- Y1 HASTA Y2 HAGA
LLAMAR POSICIONAR_CURSOR(X1, J)
LLAMAR RETRASO(TIEMPO)
ESCRIBA SIMBOLO

LLAMAR POSICIONAR_CURSOR(X2, J)
LLAMAR RETRASO(TIEMPO)
ESCRIBA SIMBOLO
FIN PARA
LLAMAR COLOR_TEXTO(15)//15 BLANCO
FIN
//----------------------------------------------------
PROCEDIMIENTO RETRASO(ENTERO MILISEG)
ENTERO J, N
REAL S
INICIO
S <- 0
N <- MILISEG*5
PARA J<-1 HASTA N HAGA
S <- S+J
S<- S -J
FIN PARA
FIN
//----------------------------------------------------
PROCEDIMIENTO MENU(VAR CARACTER OPCION)
INICIO
    LLAMAR RECUADRO(13,3,55,19,11,CAR(219),100)
LLAMAR POSICIONAR_CURSOR(20,5)
ESCRIBA "APLICACION REGISTRO DE NOTAS"
LLAMAR POSICIONAR_CURSOR(15,7)
ESCRIBA "A. INGRESAR ALUMNO"
LLAMAR POSICIONAR_CURSOR(15,8)
ESCRIBA "B. LISTADO GENERAL"
LLAMAR POSICIONAR_CURSOR(15,9)
ESCRIBA "C. LISTADO ORDEN ALFABETICO"
LLAMAR POSICIONAR_CURSOR(15,10)
ESCRIBA "D. LISTADO DESCENDENTE POR PROMEDIO"
LLAMAR POSICIONAR_CURSOR(15,11)
ESCRIBA "E. NOTA PROMEDIO MAXIMA"
LLAMAR POSICIONAR_CURSOR(15,12)
ESCRIBA "F. LISTADO DE ALUMNOS APROBADOS"
LLAMAR POSICIONAR_CURSOR(15,13)
ESCRIBA "G. LISTADO DE ALUMNOS DESAPROBADOS"

LLAMAR POSICIONAR_CURSOR(15,14)
ESCRIBA "H. RESUMEN (APROBADOS/DESAPROBADOS)"

LLAMAR POSICIONAR_CURSOR(15,15)
ESCRIBA "I. BUSCAR POR CODIGO"

LLAMAR POSICIONAR_CURSOR(15,16)
ESCRIBA "Z. SALIR"
LLAMAR POSICIONAR_CURSOR(15,17)
ESCRIBA "INGRESE SU OPCION: "
LEA OPCION
FIN
//--------------------------------------------------
PROCEDIMIENTO INGRESO(VAR ENTERO N, VAR ARREGLO[200]  DE REG_ALUMNO ARR_REGISTRO)
INICIO
LLAMAR RECUADRO(2,3,60,14,14,CAR(178),100)//14 AMARILLO
N <- N+1 //ACTUALIZA EL INDICE DONDE SE VA A GUARDAR
LLAMAR POSICIONAR_CURSOR(4,5)
ESCRIBA "INGRESE CODIGO: "
LEA ARR_REGISTRO[N].CODIGO

LLAMAR POSICIONAR_CURSOR(4,6)
ESCRIBA "INGRESE NOMBRE:"
LEA ARR_REGISTRO[N].ALUMNO

LLAMAR POSICIONAR_CURSOR(4,7)
ESCRIBA "INGRESE EL CURSO:"
LEA ARR_REGISTRO[N].CURSO

LLAMAR POSICIONAR_CURSOR(4,8)
ESCRIBA "INGRESE PRACTICA 1:"
LEA ARR_REGISTRO[N].P1

LLAMAR POSICIONAR_CURSOR(4,9)
ESCRIBA "INGRESE PRACTICA 2:"
LEA ARR_REGISTRO[N].P2

LLAMAR POSICIONAR_CURSOR(4,10)
ESCRIBA "INGRESE PRACTICA 3:"
LEA ARR_REGISTRO[N].P3
//CALCULANDO EL PROMEDIO
ARR_REGISTRO[N].PROMEDIO <- ( ARR_REGISTRO[N].P1+ ARR_REGISTRO[N].P2+ ARR_REGISTRO[N].P3 )/3
//MOSTRANDO EL PROMEDIO
LLAMAR POSICIONAR_CURSOR(4,11)
ESCRIBA "PROMEDIO: ", ARR_REGISTRO[N].PROMEDIO
//MOSTRANDO EL ESTADO
LLAMAR POSICIONAR_CURSOR(4,12)
SI (ARR_REGISTRO[N].PROMEDIO>=10.5) ENTONCES
ESCRIBA "ESTADO: APROBADO"
SINO
ESCRIBA "ESTADO: DESAPROBADO"
FIN SI
FIN
//------------------------------------------
PROCEDIMIENTO INICIALIZAR(VAR ENTERO N, VAR ARREGLO[200]  DE REG_ALUMNO ARR_REGISTRO)
//CARGA DATOS DE EJEMPLO
INICIO
ARR_REGISTRO[1].ALUMNO <- "CHINCHAY GALLEGO WALTER"
ARR_REGISTRO[1].P1 <- 15
ARR_REGISTRO[1].P2 <- 16
ARR_REGISTRO[1].P3 <- 17
ARR_REGISTRO[1].PROMEDIO <- 16 //(CALCULADO)
ARR_REGISTRO[1].CODIGO <- "11"
ARR_REGISTRO[1].CURSO <- "MATEMATICA I"

ARR_REGISTRO[2].ALUMNO <- "BENITES VILLAR CESAR"
ARR_REGISTRO[2].P1 <- 16
ARR_REGISTRO[2].P2 <- 16
ARR_REGISTRO[2].P3 <- 17
ARR_REGISTRO[2].PROMEDIO <- 16.33
ARR_REGISTRO[2].CODIGO <- "12"
ARR_REGISTRO[2].CURSO <- "MATEMATICA I"

ARR_REGISTRO[3].ALUMNO <- "HERRADA PINTADO JULIO"
ARR_REGISTRO[3].P1 <- 11
ARR_REGISTRO[3].P2 <- 9
ARR_REGISTRO[3].P3 <- 10
ARR_REGISTRO[3].PROMEDIO <- 10
ARR_REGISTRO[3].CODIGO <- "13"
ARR_REGISTRO[3].CURSO <- "SISTEMICA"

ARR_REGISTRO[4].ALUMNO <- "HUERTAS ANDRADE KEVIN"
ARR_REGISTRO[4].P1 <- 17
ARR_REGISTRO[4].P2 <- 19
ARR_REGISTRO[4].P3 <- 13
ARR_REGISTRO[4].PROMEDIO <- 16.33
ARR_REGISTRO[4].CODIGO <- "14"
ARR_REGISTRO[4].CURSO <- "REDACCION"

ARR_REGISTRO[5].ALUMNO <- "ZAPATA VEGA INES"
ARR_REGISTRO[5].P1 <- 6
ARR_REGISTRO[5].P2 <- 7
ARR_REGISTRO[5].P3 <- 12
ARR_REGISTRO[5].PROMEDIO <- 8.33
ARR_REGISTRO[5].CODIGO <- "15"
ARR_REGISTRO[5].CURSO <- "INGLES I"

ARR_REGISTRO[6].ALUMNO <- "MORALES VELIZ MICHAEL"
ARR_REGISTRO[6].P1 <- 12
ARR_REGISTRO[6].P2 <- 16
ARR_REGISTRO[6].P3 <- 10
ARR_REGISTRO[6].PROMEDIO <- 12.66
ARR_REGISTRO[6].CODIGO <- "16"
ARR_REGISTRO[6].CURSO <- "SISTEMICA"

N <- 6 //SE ACTUALIZA EL VALOR DE N
FIN
//-------------------------------------------
PROCEDIMIENTO LISTADO_GENERAL(ENTERO N, ARREGLO[200]  DE REG_ALUMNO ARR_REGISTRO)
ENTERO J, K
INICIO
//CABECERAS
LLAMAR POSICIONAR_CURSOR(1,4)
ESCRIBA "NRO"
LLAMAR POSICIONAR_CURSOR(5,4)
ESCRIBA "COD."
LLAMAR POSICIONAR_CURSOR(10,4)
ESCRIBA "ALUMNO"
LLAMAR POSICIONAR_CURSOR(34,4)
ESCRIBA "CURSO"
LLAMAR POSICIONAR_CURSOR(52,4)
ESCRIBA "P1"
LLAMAR POSICIONAR_CURSOR(56,4)
ESCRIBA "P2"
LLAMAR POSICIONAR_CURSOR(60,4)
ESCRIBA "P3"
LLAMAR POSICIONAR_CURSOR(64,4)
ESCRIBA "PROM"
LLAMAR POSICIONAR_CURSOR(70,4)
ESCRIBA "ESTADO"
LLAMAR POSICIONAR_CURSOR(1,5)
ESCRIBA "============================================================================="
K<- 1 //NRO DE ORDEN
PARA J <- 1 HASTA N HAGA
LLAMAR POSICIONAR_CURSOR(1,K+5)
ESCRIBA K, ".-"
LLAMAR POSICIONAR_CURSOR(5,K+5)
ESCRIBA ARR_REGISTRO[J].CODIGO

LLAMAR POSICIONAR_CURSOR(10,K+5)
ESCRIBA ARR_REGISTRO[J].ALUMNO

LLAMAR POSICIONAR_CURSOR(34,K+5)
ESCRIBA ARR_REGISTRO[J].CURSO
LLAMAR POSICIONAR_CURSOR(52,K+5)
ESCRIBA ARR_REGISTRO[J].P1
LLAMAR POSICIONAR_CURSOR(56,K+5)
ESCRIBA ARR_REGISTRO[J].P2
LLAMAR POSICIONAR_CURSOR(60,K+5)
ESCRIBA ARR_REGISTRO[J].P3
LLAMAR POSICIONAR_CURSOR(64,K+5)

SI (ARR_REGISTRO[J].PROMEDIO>=10.5) ENTONCES
LLAMAR COLOR_TEXTO(9) //AZUL
ESCRIBA ARR_REGISTRO[J].PROMEDIO
LLAMAR POSICIONAR_CURSOR(70,K+5)
ESCRIBA "APROBADO"
SINO
LLAMAR COLOR_TEXTO(12) //ROJO
ESCRIBA ARR_REGISTRO[J].PROMEDIO
LLAMAR POSICIONAR_CURSOR(70,K+5)
ESCRIBA "DESAPROBADO"
fin si
//REGRESANDO EL COLOR BLANCO
LLAMAR COLOR_TEXTO(15)//15 BLANCO
K <- K+1
FIN PARA
FIN
//------------------------------------------------------
PROCEDIMIENTO ORDENAR_ALFAB(ENTERO N, VAR ARREGLO[200] DE REG_ALUMNO ARR_REGISTRO)
REG_ALUMNO AUX //LA VARIABLE AUXILIAR
ENTERO J
BOOLEANO ORDENADO
INICIO
ORDENADO <- FALSO
MIENTRAS (ORDENADO = FALSO) HAGA
ORDENADO <- VERDADERO
PARA J <- 1 HASTA N-1 HAGA
SI(ARR_REGISTRO[J].ALUMNO > ARR_REGISTRO[J+1].ALUMNO) ENTONCES
//SE INTERCAMBIA
AUX <- ARR_REGISTRO[J]
ARR_REGISTRO[J] <- ARR_REGISTRO[J+1]
ARR_REGISTRO[J+1] <- AUX
ORDENADO <- FALSO
FIN SI
FIN PARA
FIN MIENTRAS
FIN
//-------------------------------------------------------
FUNCION PROMEDIO_MAX(ENTERO N, ARREGLO[200] DE REG_ALUMNO ARR_REGISTRO): REAL
//RETORMA EL PROMEDIO MAYOR
REAL PROM_MAY
ENTERO J
INICIO
PROM_MAY<- ARR_REGISTRO[1].PROMEDIO
PARA J<- 1 HASTA N HAGA
SI (ARR_REGISTRO[J].PROMEDIO > PROM_MAY) ENTONCES
PROM_MAY <- ARR_REGISTRO[J].PROMEDIO
FIN SI
FIN PARA
RETORNE PROM_MAY
FIN
//-------------------------------------------------------
PROCEDIMIENTO LISTADO_POR_ESTADO(ENTERO N, ARREGLO[200]  DE REG_ALUMNO ARR_REGISTRO, ENTERO ESTADO)
 //ESTADO: 1 LISTA APROBADOS   2: LISTA DESAPROBADOS
ENTERO J, K
INICIO
//CABECERAS
LLAMAR POSICIONAR_CURSOR(1,4)
ESCRIBA "NRO"
LLAMAR POSICIONAR_CURSOR(6,4)
ESCRIBA "ALUMNO"
LLAMAR POSICIONAR_CURSOR(30,4)
ESCRIBA "P1"
LLAMAR POSICIONAR_CURSOR(38,4)
ESCRIBA "P2"
LLAMAR POSICIONAR_CURSOR(46,4)
ESCRIBA "P3"
LLAMAR POSICIONAR_CURSOR(54,4)
ESCRIBA "PROMEDIO"
LLAMAR POSICIONAR_CURSOR(65,4)
ESCRIBA "ESTADO"
LLAMAR POSICIONAR_CURSOR(1,5)
ESCRIBA "======================================================================"
SI (ESTADO = 1) ENTONCES
K<- 1 //NRO DE ORDEN
PARA J <- 1 HASTA N HAGA
SI (ARR_REGISTRO[J].PROMEDIO>=10.5) ENTONCES
LLAMAR POSICIONAR_CURSOR(1,K+5)
ESCRIBA K, ".-"
LLAMAR POSICIONAR_CURSOR(6,K+5)
ESCRIBA ARR_REGISTRO[J].ALUMNO
LLAMAR POSICIONAR_CURSOR(30,K+5)
ESCRIBA ARR_REGISTRO[J].P1
LLAMAR POSICIONAR_CURSOR(38,K+5)
ESCRIBA ARR_REGISTRO[J].P2
LLAMAR POSICIONAR_CURSOR(46,K+5)
ESCRIBA ARR_REGISTRO[J].P3
LLAMAR POSICIONAR_CURSOR(54,K+5)
SI (ARR_REGISTRO[J].PROMEDIO>=10.5) ENTONCES
LLAMAR COLOR_TEXTO(9) //AZUL
ESCRIBA ARR_REGISTRO[J].PROMEDIO
LLAMAR POSICIONAR_CURSOR(65,K+5)
ESCRIBA "APROBADO"
SINO
LLAMAR COLOR_TEXTO(12) //ROJO
ESCRIBA ARR_REGISTRO[J].PROMEDIO
LLAMAR POSICIONAR_CURSOR(65,K+5)
ESCRIBA "DESAPROBADO"
fin si
//REGRESANDO EL COLOR BLANCO
LLAMAR COLOR_TEXTO(15)//15 BLANCO
K <- K+1
FIN SI
FIN PARA
SINO //CUANDO ESTADO VALE 2: LISTA DE DESAPROBADOS
K<- 1 //NRO DE ORDEN
PARA J <- 1 HASTA N HAGA
SI (ARR_REGISTRO[J].PROMEDIO < 10.5) ENTONCES
LLAMAR POSICIONAR_CURSOR(1,K+5)
ESCRIBA K, ".-"
LLAMAR POSICIONAR_CURSOR(6,K+5)
ESCRIBA ARR_REGISTRO[J].ALUMNO
LLAMAR POSICIONAR_CURSOR(30,K+5)
ESCRIBA ARR_REGISTRO[J].P1
LLAMAR POSICIONAR_CURSOR(38,K+5)
ESCRIBA ARR_REGISTRO[J].P2
LLAMAR POSICIONAR_CURSOR(46,K+5)
ESCRIBA ARR_REGISTRO[J].P3
LLAMAR POSICIONAR_CURSOR(54,K+5)
SI (ARR_REGISTRO[J].PROMEDIO>=10.5) ENTONCES
LLAMAR COLOR_TEXTO(9) //AZUL
ESCRIBA ARR_REGISTRO[J].PROMEDIO
LLAMAR POSICIONAR_CURSOR(65,K+5)
ESCRIBA "APROBADO"
SINO
LLAMAR COLOR_TEXTO(12) //ROJO
ESCRIBA ARR_REGISTRO[J].PROMEDIO
LLAMAR POSICIONAR_CURSOR(65,K+5)
ESCRIBA "DESAPROBADO"
fin si
//REGRESANDO EL COLOR BLANCO
LLAMAR COLOR_TEXTO(15)//15 BLANCO
K <- K+1
FIN SI
FIN PARA
FIN SI
FIN
//------------------------------------------------------
FUNCION NRO_APROBADOS(ENTERO N, ARREGLO[200] DE REG_ALUMNO ARR_REGISTRO):ENTERO
ENTERO CONT, J
INICIO
CONT <- 0
PARA J<- 1 HASTA N HAGA
SI(ARR_REGISTRO[J].PROMEDIO >= 10.5) ENTONCES
CONT <- CONT + 1
FIN SI
FIN PARA
RETORNE CONT
FIN
//-----------------------------------------------------
FUNCION BUSCAR_COD(ENTERO N, ARREGLO[200] DE REG_ALUMNO ARR_REGISTRO, CADENA[5] VALORBUSCAR): ENTERO
//BUSCA EL VALORBUSCAR DENTRO DEL ARREGLO
//SI LO ENCUENTRA RETORNA LA POSICION DEL ARREGLO
//SINO, RETORNA -1
ENTERO J
INICIO
PARA J <- 1 HASTA N HAGA
SI (VALORBUSCAR=ARR_REGISTRO[J].CODIGO) ENTONCES
//YA LO ENCONTRÓ
RETORNE J //J ES LA POSICION
FIN SI
FIN PARA
RETORNE -1 //NO LO ENCONTRÓ
FIN
//----------------------------------------------------------
//--- EL MODULO PRINCIPAL -----

INICIO
N <- 0 //INICIALIZANDO N
LLAMAR INICIALIZAR(N, ARR_REGISTRO)
LLAMAR LIMPIAR_PANTALLA()
LLAMAR COLOR_TEXTO(15)//15 BLANCO

OPCION <- 'X' //VALOR INICIAL PARA Q ENTRE LA 1RA VEZ
MIENTRAS (OPCION<>'Z')Y(OPCION<>'z') HAGA
LLAMAR LIMPIAR_PANTALLA()
LLAMAR MENU(OPCION)
LLAMAR LIMPIAR_PANTALLA()
CASO OPCION
'A','a': ESCRIBA "A. INGRESO DE ALUMNO"
LLAMAR POSICIONAR_CURSOR(1,4)
LLAMAR INGRESO(N, ARR_REGISTRO)
'B','b': ESCRIBA "B. LISTADO GENERAL"
LLAMAR LISTADO_GENERAL(N,ARR_REGISTRO)
'C','c': ESCRIBA "C. LISTADO EN ORDEN ALFABETICO"
LLAMAR ORDENAR_ALFAB(N, ARR_REGISTRO)//LO ORDENA
LLAMAR LISTADO_GENERAL(N,ARR_REGISTRO)//LO MUESTRA
'E','e': ESCRIBA "E. NOTA PROMEDIO MAXIMA"
LLAMAR LISTADO_GENERAL(N,ARR_REGISTRO)//LO MUESTRA
LLAMAR POSICIONAR_CURSOR(3,20)
PMAY <- PROMEDIO_MAX(N, ARR_REGISTRO)
ESCRIBA "EL PROMEDIO MAXIMO ES: ", PMAY
'F','f': ESCRIBA "F. LISTADO DE APROBADOS"
LLAMAR LISTADO_POR_ESTADO(N, ARR_REGISTRO,1)
'G','g': ESCRIBA "G. LISTADO DE DESAPROBADOS"
LLAMAR LISTADO_POR_ESTADO(N, ARR_REGISTRO,2)
'H','h': ESCRIBA "H. RESUMEN"
LLAMAR POSICIONAR_CURSOR(3,5)
ESCRIBA "TOTAL ALUMNOS: ", N
LLAMAR POSICIONAR_CURSOR(3,6)
ESCRIBA "NRO. APROBADOS: ", NRO_APROBADOS(N,ARR_REGISTRO)
LLAMAR POSICIONAR_CURSOR(3,7)
//ESCRIBA "NRO. DESAPROBADOS: ", NRO_DESAPROBADOS(N,ARR_REGISTRO)
'I','i': LLAMAR RECUADRO(1,1,80,22,13,'*', 10)
LLAMAR POSICIONAR_CURSOR(3,3)
ESCRIBA "I. BUSCAR POR CODIGO"

LLAMAR POSICIONAR_CURSOR(3,6)
ESCRIBA "INGRESE EL CODIGO DEL ALUMNO A BUSCAR: "
LEA COD
POS <- BUSCAR_COD(N,ARR_REGISTRO,COD)
SI (POS= -1) ENTONCES //NO LO ENCONTRÓ
LLAMAR RECUADRO(23,10,67,15,12,CAR(5),30)
LLAMAR POSICIONAR_CURSOR(27,12)
ESCRIBA "CODIGO DE ALUMNO NO ENCONTRADO"
SINO //SÍ SE ENCUENTRA

LLAMAR RECUADRO(3,8,60,20,11,CAR(177),15)

LLAMAR POSICIONAR_CURSOR(5,9)
ESCRIBA "CODIGO: ", ARR_REGISTRO[POS].CODIGO

LLAMAR POSICIONAR_CURSOR(5,10)
ESCRIBA "ALUMNO: ", ARR_REGISTRO[POS].ALUMNO

LLAMAR POSICIONAR_CURSOR(5,11)
ESCRIBA "CURSO: ", ARR_REGISTRO[POS].CURSO

LLAMAR POSICIONAR_CURSOR(5,12)
ESCRIBA "PRACTICA 1: ", ARR_REGISTRO[POS].P1

LLAMAR POSICIONAR_CURSOR(5,13)
ESCRIBA "PRACTICA 2: ", ARR_REGISTRO[POS].P2

LLAMAR POSICIONAR_CURSOR(5,14)
ESCRIBA "PRACTICA 3: ", ARR_REGISTRO[POS].P3

LLAMAR POSICIONAR_CURSOR(5,15)
ESCRIBA "PROMEDIO: ", ARR_REGISTRO[POS].PROMEDIO



FIN SI
FIN CASO
LLAMAR OBTENER_CARACTER()//ESPERA PULSACION DE UNA TECLA
FIN MIENTRAS
LLAMAR LIMPIAR_PANTALLA()
LLAMAR POSICIONAR_CURSOR(30,5)
ESCRIBA "GRACIAS. HASTA PRONTO"
FIN